diff --git a/constants/seasons/parts.s b/constants/seasons/parts.s
index a801699a..882a0a9a 100644
--- a/constants/seasons/parts.s
+++ b/constants/seasons/parts.s
@@ -41,8 +41,8 @@
 .define PART_KING_MOBLINS_CANNONS $2d
 
 ;;
-; created by facade - holes?
-.define PART_2e $2e
+; Created by facade to temporarily make holes.
+.define PART_FACADE_HOLE_MAKER $2e
 
 ;;
 .define PART_2f $2f
diff --git a/object_code/seasons/enemies/facade.s b/object_code/seasons/enemies/facade.s
index 2bab385d..033b0d68 100644
--- a/object_code/seasons/enemies/facade.s
+++ b/object_code/seasons/enemies/facade.s
@@ -1,315 +1,448 @@
 ; ==================================================================================================
 ; ENEMY_FACADE
+;
+; Variables:
+;   var03: The attack that has been randomly chosen.
+;   var30: The number of Beetles that have been spawned by the Beetle attack.
 ; ==================================================================================================
 enemyCode71:
 	jr z,@normalStatus
-	sub $03
+	sub ENEMYSTATUS_NO_HEALTH
 	ret c
 	ret nz
-	; dead
-	ld e,$a4
+
+	; Dead
+	ld e,Enemy.collisionType
 	ld a,(de)
 	or a
-	call nz,@dead
-	ld e,$82
+	call nz,facadeKillSpawnedBeetles
+
+	ld e,Enemy.subid
 	ld a,(de)
 	or a
 	jp nz,enemyDie
 	jp enemyBoss_dead
 
 @normalStatus:
-	ld e,$84
+	ld e,Enemy.state
 	ld a,(de)
 	rst_jumpTable
-	.dw @state0
-	.dw @stateStub
-	.dw @stateStub
-	.dw @stateStub
-	.dw @stateStub
-	.dw @stateStub
-	.dw @stateStub
-	.dw @stateStub
-	.dw @state8
-	.dw @state9
-	.dw @stateA
-	.dw @stateB
-	.dw @stateC
-
-@state0:
+	.dw facade_state_uninitialized
+	.dw facade_state_stub
+	.dw facade_state_stub
+	.dw facade_state_stub
+	.dw facade_state_stub
+	.dw facade_state_stub
+	.dw facade_state_stub
+	.dw facade_state_stub
+	.dw facade_state_waiting
+	.dw facade_state_chooseAttackAndBecomeVisible
+	.dw facade_state_waitAndRumble
+	.dw facade_state_attack
+	.dw facade_state_resetAndInvisible
+
+; Do different initialization depending on [subId]:
+;   zero:     Just wait.
+;   non-zero: Start the fight.
+facade_state_uninitialized:
 	call ecom_setSpeedAndState8
-	ld l,$8b
+
+	ld l,Enemy.yh
 	ld (hl),$58
-	ld l,$8d
+	ld l,Enemy.xh
 	ld (hl),$78
-	ld e,$82
+
+	; If subid == 0, jump to enemyBoss_initializeRoom.
+	ld e,Enemy.subid
 	ld a,(de)
 	or a
 	ld a,$ff
 	ld b,$00
 	jp z,enemyBoss_initializeRoom
-	ld l,$86
+
+	; If subid is non-zero, start the fight.
+	ld l,Enemy.counter1
 	ld (hl),$3c
-	ld l,$84
+
+	; [state] = 9
+	ld l,Enemy.state
 	inc (hl)
 	ret
 
-@stateStub:
+facade_state_stub:
 	ret
 
-@state8:
+; Waiting for Link to enter the fight. Only entered when subId is 0.
+facade_state_waiting:
+	; If Link is below $58, the fight is triggered.
 	ldh a,(<hEnemyTargetY)
 	cp $58
 	ret c
+
+	; [state]++
 	ld h,d
 	ld l,e
 	inc (hl)
-	ld l,$86
+
+	; [counter1] = 1
+	; facade_state_chooseAttackAndBecomeVisible decrements counter1, and we don't want it to go below 0.
+	ld l,Enemy.counter1
 	inc (hl)
-	ld a,$2d
+
+	ld a,MUS_MINIBOSS
 	ld (wActiveMusic),a
 	jp playSound
 
-@state9:
+facade_state_chooseAttackAndBecomeVisible:
+	; Wait for [counter1] to be zero.
 	call ecom_decCounter1
 	ret nz
+
+	; [counter1] = $78
 	ld a,$78
 	ld (hl),a
+
+	; [state]++
 	ld l,e
 	inc (hl)
-	ld l,$a4
+
+	; Enable collision.
+	ld l,Enemy.collisionType
 	set 7,(hl)
+
 	call setScreenShakeCounter
+
+	; Choose a random attack, biased towards Volcano Rock. Put it in var03.
 	call getRandomNumber_noPreserveVars
 	and $03
-	ld hl,@table_48c4
+	ld hl,table_facade_attack
 	rst_addAToHl
-	ld e,$83
+	ld e,Enemy.var03
 	ld a,(hl)
 	ld (de),a
-	ld a,$b8
+
+	ld a,SND_RUMBLE2
 	call playSound
+
 	xor a
 	call enemySetAnimation
+
 	jp objectSetVisible83
 
-@table_48c4:
+table_facade_attack:
+	; Spawn Beetles.
 	.db $00
+	; Make holes under Link.
 	.db $01
+	; Spawn Volcano Rocks.
 	.db $02
 	.db $02
 
-@stateA:
+facade_state_waitAndRumble:
 	call ecom_decCounter1
-	jr z,+
+	jr z,@nextState
+
 	ld a,(hl)
 	and $1f
-	ld a,$b8
+
+	; Rumble when [counter1] & $1f == 0.
+	ld a,SND_RUMBLE2
 	call z,playSound
-	jr ++
-+
+	jr @onlyAnimate
+
+@nextState:
+	; [state]++
 	ld l,e
 	inc (hl)
+
+	; [substate] = 0, preparing for below.
 	inc l
 	ld (hl),$00
-++
+
+@onlyAnimate:
 	jp enemyAnimate
 
-@stateB:
+; Attack, based on the previously chosen value in var03.
+; These attacks make use of substate.
+facade_state_attack:
 	call enemyAnimate
-	ld e,$83
+
+	ld e,Enemy.var03
 	ld a,(de)
 	rst_jumpTable
-	.dw @var03_00
-	.dw @var03_01
-	.dw @var03_02
+	.dw @attack_beetle
+	.dw @attack_holeMaker
+	.dw @attack_volcanoRock
 
-@var03_00:
-	ld e,$85
+@attack_beetle:
+	ld e,Enemy.substate
 	ld a,(de)
 	rst_jumpTable
-	.dw @@substate0
-	.dw @@substate1
-	.dw @@substate2
+	.dw @@attack_beetle_setup
+	.dw @@attack_beetle_wait
+	.dw @@attack_beetle_spawn
 
-@@substate0:
+@@attack_beetle_setup:
+	; [substate]++
 	ld h,d
 	ld l,e
 	inc (hl)
 	inc l
+
+	; [counter1] = $14
 	ld (hl),$14
 	ret
 
-@@substate1:
+@@attack_beetle_wait:
 	call ecom_decCounter1
 	ret nz
+
+	; [counter1] = $46
 	ld (hl),$46
+
+	; [substate]++
 	ld l,e
 	inc (hl)
 	ret
 
-@@substate2:
+; Spawn 5 Beetles that fall from the ceiling.
+@@attack_beetle_spawn:
 	call ecom_decCounter1
-	jp z,@func_49e3
+	jp z,facadeIncrementStateAndFadeOut
+
+	; Spawn Beetles when ([counter1] & $0f) == 0.
 	ld a,(hl)
 	and $0f
 	ret nz
-	ld l,$b0
+
+	; We only spawn 5 Beetles at most.
+	ld l,Enemy.var30
 	ld a,(hl)
 	cp $05
 	ret nc
-	jp @func_498c
 
-@var03_01:
-	ld e,$85
+	jp facade_spawnBeetle
+
+@attack_holeMaker:
+	ld e,Enemy.substate
 	ld a,(de)
 	rst_jumpTable
-	.dw @@substate0
-	.dw @@substate1
-	.dw @@substate2
+	.dw @@attack_holeMaker_setup
+	.dw @@attack_holeMaker_animateAndInvisible
+	.dw @@attack_holeMaker_spawn
 
-@@substate0:
+@@attack_holeMaker_setup:
+	; [substate] = $01
 	ld a,$01
 	ld (de),a
+
+	; Set animation $02.
 	inc a
 	jp enemySetAnimation
 
-@@substate1:
+@@attack_holeMaker_animateAndInvisible:
+	; Wait for [animParameter] == $7f. This happens in 24 frames.
 	ld h,d
-	ld l,$a1
+	ld l,Enemy.animParameter
 	bit 7,(hl)
 	jp z,enemyAnimate
+
+	; [substate]++
 	ld l,e
 	inc (hl)
-	ld l,$86
+
+	ld l,Enemy.counter1
 	ld (hl),$b4
-	ld l,$a4
+
+	; Disable collision.
+	ld l,Enemy.collisionType
 	res 7,(hl)
+
 	jp objectSetInvisible
 
-@@substate2:
+@@attack_holeMaker_spawn:
 	call ecom_decCounter1
-	jp z,@func_49e3
+	jp z,facadeIncrementStateAndFadeOut
+
+	; Wait for ([counter1] & $1f) == 0
 	ld a,(hl)
 	and $1f
 	ret nz
-	jp @func_49b2
 
-@var03_02:
-	ld e,$85
+	jp facade_spawnHoleMaker
+
+@attack_volcanoRock:
+	ld e,Enemy.substate
 	ld a,(de)
 	rst_jumpTable
-	.dw @@substate0
-	.dw @@substate1
+	.dw @@attack_volcanoRock_setup
+	.dw @@attack_volcanoRock_spawn
 
-@@substate0:
+@@attack_volcanoRock_setup:
+	; substate++
 	ld h,d
 	ld l,e
 	inc (hl)
+
+	; counter1 = $f0
 	inc l
 	ld (hl),$f0
+
+	; Load animation $01.
+	; animParameter is 28 frames of $00 and 32 of $01 in a loop.
 	ld a,$01
 	jp enemySetAnimation
 
-@@substate1:
+; Spawn Volcano Rocks.
+; The combination of criteria ([counter1] & $0f == 0 && [animParameter] == 1) leads to us spawning 3 groups of 2.
+@@attack_volcanoRock_spawn:
 	call ecom_decCounter1
-	jp z,@func_49e3
+	jp z,facadeIncrementStateAndFadeOut
+
+	; Only spawn if (counter1 & $0f) == 0
 	ld a,(hl)
 	and $0f
 	ret nz
-	ld e,$a1
+
+	; Return if animParameter != 1.
+	ld e,Enemy.animParameter
 	ld a,(de)
 	dec a
 	ret nz
-	ld a,$51
+
+	ld a,SND_THROW
 	call playSound
-	jp @func_49d9
 
-@stateC:
+	jp facade_spawnVolcanoRock
+
+; After the attack, Facade closes its eyes and goes invisible, before choosing another attack.
+facade_state_resetAndInvisible:
+	; Facade is on animation 2 here.
+	; Wait for animParameter to be $ff (24 frames).
 	ld h,d
-	ld l,$a1
+	ld l,Enemy.animParameter
 	bit 7,(hl)
 	jp z,enemyAnimate
+
+	; [state] = $09
 	ld l,e
 	ld (hl),$09
-	ld l,$86
+
+	ld l,Enemy.counter1
 	ld (hl),$78
-	ld l,$a4
+
+	; Disable collision.
+	ld l,Enemy.collisionType
 	res 7,(hl)
+
 	jp objectSetInvisible
 
-@func_498c:
+; Spawn a Beetle with subid $01 (ie, Beetle falls in from sky).
+facade_spawnBeetle:
 	ld b,ENEMY_BEETLE
 	call ecom_spawnEnemyWithSubid01
 	ret nz
-	ld l,$96
-	ld a,$80
+
+	; [Beetle.relatedObj1] = Facade
+	ld l,Enemy.relatedObj1
+	ld a,Enemy
 	ldi (hl),a
 	ld (hl),d
-	ld e,$b0
+
+	; [Facade.var30]++
+	ld e,Enemy.var30
 	ld a,(de)
 	inc a
 	ld (de),a
+
+	; Randomize [Beetle.yh].
 	call getRandomNumber
+	; Save the random number to c to use below.
 	ld c,a
 	and $70
 	add $20
-	ld l,$8b
+	ld l,Enemy.yh
 	ldi (hl),a
+
+	; Randomize [Beetle.xh].
 	inc l
 	ld a,c
 	and $07
 	swap a
 	add $40
 	ld (hl),a
+
 	ret
 
-@func_49b2:
-	ld b,PART_2e
+; Spawn the FACADE_HOLE_MAKER on a random tile on the 3x3 grid of tiles that
+; has Link at its centre.
+facade_spawnHoleMaker:
+	ld b,PART_FACADE_HOLE_MAKER
 	call ecom_spawnProjectile
 	ret nz
+
+	; Set b and c to random numbers < $1f.
 	push hl
 	ld bc,$1f1f
 	call ecom_randomBitwiseAndBCE
 	pop hl
+
+	; [yh] = ([<hEnemyTargetY] + b - $10) & $f0 + $08
+	; This chooses a tile from one tile below to one tile above Link,
+	; biased to whichever is closer.
 	ldh a,(<hEnemyTargetY)
 	add b
 	sub $10
 	and $f0
 	add $08
-	ld l,$cb
+	ld l,Part.yh
 	ld (hl),a
+
+	; [xh] = ([<hEnemyTargetX] + c - $10) & $f0 + $08
+	; This chooses a tile from one tile left to one tile right of Link,
+	; biased to whichever is closer.
 	ldh a,(<hEnemyTargetX)
 	add c
 	sub $10
 	and $f0
 	add $08
-	ld l,$cd
+	ld l,Part.xh
 	ld (hl),a
+
 	ret
 
-@func_49d9:
+facade_spawnVolcanoRock:
 	ld b,PART_VOLCANO_ROCK
 	call ecom_spawnProjectile
 	ret nz
-	ld l,$c2
+
+	; [subid] = 1 - volcano.
+	ld l,Part.subid
 	inc (hl)
+
 	ret
 
-@func_49e3:
-	ld l,$84
+; This is used by the attack states to move to the next state and set the animation that closes its eyes.
+facadeIncrementStateAndFadeOut:
+	ld l,Enemy.state
 	inc (hl)
+
 	ld a,$02
 	jp enemySetAnimation
 
-@dead:
+; Kill all the Beetles that were spawned.
+facadeKillSpawnedBeetles:
 	ld hl,$d080
--
-	ld l,$81
+@loop:
+	ld l,Enemy.id
 	ld a,(hl)
-	cp $51
+	cp ENEMY_BEETLE
 	call z,ecom_killObjectH
+
+	; Loop h from $d0 to $e0.
 	inc h
 	ld a,h
 	cp $e0
-	jr c,-
+	jr c,@loop
+
 	ret
diff --git a/object_code/seasons/parts/2e.s b/object_code/seasons/parts/2e.s
deleted file mode 100644
index bc088ba2..00000000
--- a/object_code/seasons/parts/2e.s
+++ /dev/null
@@ -1,48 +0,0 @@
-; ==================================================================================================
-; PART_2e
-; ==================================================================================================
-partCode2e:
-	ld e,$c4
-	ld a,(de)
-	or a
-	jr z,++
-	ld e,$e1
-	ld a,(de)
-	or a
-	jr z,+
-	bit 7,a
-	jp nz,partDelete
-	call func_6853
-+
-	jp partAnimate
-++
-	ld a,$01
-	ld (de),a
-	call objectGetTileAtPosition
-	cp $f3
-	jp z,partDelete
-	ld h,$ce
-	ld a,(hl)
-	or a
-	jp nz,partDelete
-	ld a,SND_POOF
-	call playSound
-	jp objectSetVisible83
-	
-func_6853:
-	push af
-	xor a
-	ld (de),a
-	call objectGetTileAtPosition
-	pop af
-	ld e,$f0
-	dec a
-	jr z,+
-	ld a,(de)
-	ld (hl),a
-	ret
-+
-	ld a,(hl)
-	ld (de),a
-	ld (hl),$f3
-	ret
diff --git a/object_code/seasons/parts/facadeHoleMaker.s b/object_code/seasons/parts/facadeHoleMaker.s
new file mode 100644
index 00000000..85ef3742
--- /dev/null
+++ b/object_code/seasons/parts/facadeHoleMaker.s
@@ -0,0 +1,85 @@
+; ==================================================================================================
+; PART_FACADE_HOLE_MAKER
+;
+; Facade spawns this to make temporary holes under link.
+;
+; animParameter has the following values, which are critical to the function of this part:
+;   $00 (24 frames)  : animation only.
+;   $01 (90 frames)  : change the tile to hole, storing current tile in var30.
+;   $02 (10 frames)  : revert the tile to original.
+;   $00 (20 frames)  : animation only.
+;   $ff (128 frames) : despawn.
+;
+; Variables:
+;   var30: Used to store the kind of tile that has been replaced by a hole, so that it can be reset later.
+; ==================================================================================================
+partCode2e:
+	ld e,Part.state
+	ld a,(de)
+	or a
+	jr z,@initialize
+
+	ld e,Part.animParameter
+	ld a,(de)
+	or a
+	jr z,@onlyAnimate
+
+	; Despawn if animation is complete and animParameter is $ff.
+	bit 7,a
+	jp nz,partDelete
+
+	call @modifyTile
+
+@onlyAnimate:
+	jp partAnimate
+
+; In state 0, do some initialization.
+@initialize:
+	; Set state to 1.
+	ld a,$01
+	ld (de),a
+
+	call objectGetTileAtPosition
+
+	; If this tile was already made a hole, don't do it again.
+	cp TILEINDEX_HOLE
+	jp z,partDelete
+
+	; Check if wRoomCollisions at this location is 0?
+	ld h,>wRoomCollisions
+	ld a,(hl)
+	or a
+	jp nz,partDelete
+
+	ld a,SND_POOF
+	call playSound
+
+	jp objectSetVisible83
+
+; Either make a hole or reset the tile at this position, depending on the value
+; of animParameter.
+@modifyTile:
+	; Set animParameter to 0 so we only run this once.
+	push af
+	xor a
+	ld (de),a
+	call objectGetTileAtPosition
+	pop af
+
+	ld e,Part.var30
+
+	; If [animParameter] == 1, make a hole, otherwise (if it's 2), reset.
+	dec a
+	jr z,@@makeHole
+
+	; Reset the tile to what it was before.
+	ld a,(de)
+	ld (hl),a
+	ret
+
+; Store the current kind of tile in var30, then make the tile a hole.
+@@makeHole:
+	ld a,(hl)
+	ld (de),a
+	ld (hl),TILEINDEX_HOLE
+	ret
diff --git a/seasons.s b/seasons.s
index ba2faabd..e228c5e6 100644
--- a/seasons.s
+++ b/seasons.s
@@ -675,7 +675,7 @@ m_section_free Part_Code_2 NAMESPACE partCode
 	.include "object_code/seasons/parts/wallFlameShooterFlames.s"
 	.include "object_code/seasons/parts/buriedMoldorm.s"
 	.include "object_code/seasons/parts/kingMoblinsCannons.s"
-	.include "object_code/seasons/parts/2e.s"
+	.include "object_code/seasons/parts/facadeHoleMaker.s"
 	.include "object_code/seasons/parts/2f.s"
 	.include "object_code/seasons/parts/poppableBubble.s"
 	.include "object_code/seasons/parts/33.s"